See
   http://www.webber-labs.com/wp-content/uploads/2015/08/mpl-03.pdf#page=2


G1: <subexp> ::= a | b | c | <subexp> - <subexp>


G2: <subexp> ::= <var> - <subexp> | <var>  // right associative
       <var> :: = a | b | a


G3: <subexp> ::= <subexp> - <var> | <var>  // left associative
       <var> :: = a | b | c


 Parse the same expression, b - c - a, using each of G1, G2 and G3.

 G1. Two left derivations and two parses of b - c - a using G1.

 <subexp> -> <sebexp> - <subexp> 
          -> b - <subexp>  
          -> b - <subexp> - <subexp>
          -> b - c - <subexp>
          -> b - c - a
             b - (c - a)

                   <subexp>
                  /    |   \
           <subexp>    |   <subexp>
              |        -    /  |  \
              b            /   |   \
                   <subexp>    -    <subexp>
                      |                |
                      c                a

 <subexp> -> <sebexp> - <subexp> 
          -> <sebexp> - <subexp> - <subexp>  
          -> b - <subexp> - <subexp>
          -> b - c - <subexp>
          -> b - c - a
            (b - c) - a

                   <subexp>
                  /    |    \
          <subexp>     -     <subexp>
         /   |   \             |
 <subexp>    -    <subexp>     a
    |               |
    b               c


G2. A unique left derivation and parse of b - c - a using G2.

<subexp> -> <var> - <subexp>
         -> b - <subexp>
         -> b - <var> - <subexp>
         -> b - c - <subexp>
         -> b - c - <var>
         -> b - c - a
            b - (c - a)

                   <subexp> 
                  /    |   \
              <var>    -   <subexp> 
                |          /  |   \
                b     <var>   -    <subexp> 
                        |             |
                        c           <var>
                                      |
                                      a


G3. A unique left derivation and parse of b - c - a using G3.

<subexp> -> <subexp> - <var>  
         -> <subexp> - <var> - <var>
         -> <var> - <var> - <var>
         ->   b  - <var> - <var>
         ->   b - c - <var>
         ->  b - c - a
            (b - c) - a

                   <subexp>
                  /    |    \
          <subexp>     -     <var>
         /   |   \             |
 <subexp>    -    <var>        a
    |               |
  <var>             c
    |
    b


The G2 grammar forces right associative parses.
The G3 grammar forces left associative parses.
The G1 grammar is ambiguous and does not force a particular parse.


The assignment operator in Java is right associative.

d = 4;
c = 3;
b = 2;
a = b = c = d;      // assignment is right associative
a = (b = (c = d));


The < operator in Java cannot be used in an associative way.

x < y < z   (x < y) < z    x < (y < z)  // < is NOT associative 
                                        // (in the sense that x<y<z doesn't parse)
0 < x < 1  ===>  0 < x && x < 1


1 - 2 - 3  // subtraction is "not associative" in the sense that (x-y)-z != x-(y-z)
1 + 2 + 3  // addition is associative in the sense that (x+y)+z == x+(y+z)
1 * 2 * 3  // multiplication is associative in the sense that (x*y)*z == x*(y*z)
So it makes sense for G1, G2, and G3 to use - instead of + or *.